BF2S Forums BF2/2142 Hit reg fix

/*
======================================================
Battlefield 2 HitReg Fixer 
by Delusion
======================================================
*/

SendMode Input 
#Persistent
#NoEnv 
#SingleInstance force
#InstallKeybdHook

programName=BF2 HitFixer
version=
helpguiname=Help

GoSub CreateIni
GoSub ReadIni
GoSub GGui

HotKey ~%v_HitFix%, Hitregfix, On UseErrorLevel


/*
======================================================
Tray Menu 
======================================================
*/

Menu, Tray, Tip, %programName% %version% by Delusion
Menu, Tray, NoStandard
Menu, Tray, Add, About, About
Menu, Tray, Add 
Menu, Tray, Add, Hide, Hide
Menu, Tray, Add, Show, Show
Menu, Tray, Disable, Show
Menu, Tray, Default, Show
Menu, Tray, Add 
Menu, Tray, Add, Reload 
Menu, Tray, Add, Edit 
Menu, Tray, Add 
Menu, Tray, Add, Suspend 
Menu, Tray, Add 
Menu, Tray, Add, Exit, Exit 

/*
======================================================
BF2 Process Check
======================================================
*/

SetTimer BF2ProcessCheck, 500
Process Priority, , High
return

BF2ProcessCheck:
   WinGet , szProcessName, ProcessName, A
   If szProcessName = BF2.exe ; <-- BF2 File Name Here
      {
      Suspend Off
      Menu, Tray, UnCheck, Suspend
      }
   Else
      {
      Menu, Tray, Check, Suspend
      Suspend On
      }
return

/*
======================================================
Tray Menu Actions
======================================================
*/

About:
   MsgBox, 64, About, %programName% by Delusion`n`nOriginal Idea by DupaUnit.`n`nDupaUnit Contact Email - DupaSoftware[at]gmail.com`nDelusion Contact Email - alexpersonal15[at]yahoo.com
return

Hide:
   IfWinExist,  %helpguiname%
      Winclose,  %helpguiname%
   IfWinExist,  About
      Winclose,  About
Gui, Submit, %programName% %version%
Gui, 2:Destroy
Menu, Tray, Disable, Hide
Menu, Tray, Enable, Show
guiopen:=0
return

Show:
Gui, Show, , %programName% %version%
Menu, Tray, Disable, Show
Menu, Tray, Enable, Hide
return

Reload:
Reload
return

Edit:
Edit
return

Suspend:
Suspend, Toggle
Menu, Tray, ToggleCheck, Suspend
SoundBeep, 500, 100
return

Exit:
GuiClose:
ExitApp
return


/*
======================================================
Gui
======================================================
*/

GGui:
   Gui, 1: -MaximizeBox +Theme +ToolWindow -SysMenu
   Gui, 1:Add, GroupBox, x4 y-2 w192 h36,
   Gui, 1:Font, bold
   Gui, 1:Add, Text,x8 y12,HitFixer Key :
   Gui, 1:Font,
   Gui, 1:Add, Hotkey,x86 y9 w50 h20 vHitfix, %v_Hitfix%
   Gui, 1:Add, Button,x140 y8 w50 h22 gSave , Save
   Gui, 1:Add, Button,x3 y40 w65 h22 gHelp , Help
   Gui, 1:Add, Button,x68 y40 w65 h22 gHide , Hide
   Gui, 1:Add, Button,x133 y40 w65 h22 gExit , Exit
   Gui, 1:Add, StatusBar,gStbr, 
   SB_SetText("by Delusion")
   SB_SetIcon("Shell32.dll",177) 
   Gui, 1:Show,w200 h93, %programName% %versionName%
return

Stbr:
   SB_SetText("Pwned")
   Sleep,850
   SB_SetText("by Delusion")
return

/*
======================================================
Gui Actions
======================================================
*/

Help:
   If (!guiopen)
   {
      guiopen:=1
      Gui, 2:+Owner1 -SysMenu +ToolWindow +Theme 
      Gui, 2:Font, bold
      Gui, 2:Add, Text,x8 y8, 1.
      Gui, 2:Font,
      Gui, 2:Add, Text,X+0,%A_Space%%A_Space%In BF2 Press the key you assigned HitFix to,to open the Console
      Gui, 2:Font, bold
      Gui, 2:Add, Text,x8, 2.
      Gui, 2:Font,
      Gui, 2:Add, Text,X+0,%A_Space%%A_Space%Type your Ping in the Console and Press Enter
      Gui, 2:Font, bold
      Gui, 2:Add, Text,x8, 3.
      Gui, 2:Font,
      Gui, 2:Add, Text,X+0,%A_Space%%A_Space%Done! The Script should now start typing those settings.`n%A_Space%%A_Space%You can close the Console now.
      Gui, 2:Add, Button, x226 y86 vbtn w100 Default, Close
      Gui, 2:Show, w330 h112, %helpguiname%
   }
   Else
   {
      Gui, 2:Submit
      Gui, 2:Destroy
      guiopen:=0
   }
return

2ButtonClose:
Gui2Close:
   Gui, 2:Submit
   Gui, 2:Destroy
   guiopen:=0
return

Save:
   Gui Submit, NoHide
   v_Hitfix=%Hitfix%
   IniWrite %v_Hitfix%, %A_WinDir%\BF2HitFixer.ini, Hotkeys, HitfixerKey
   Reload
return

/*
======================================================
HitReg Fix
======================================================
*/

Hitregfix:
    SetKeyDelay 10, 20
    Send {~ Down}
    Sleep 100
    Send {~ Up}
    Sleep 100
    Send,Enter Your Ping{Enter}
    Input, Interpol, T10 V,{Enter}{Esc}
if (ErrorLevel = "EndKey:Escape")
    {
        Send,{Space}-{ENTER}
        return
    }
if PingVar is not digit
    {
        Send,-.{ENTER}
        return
    }
Interpol += 5
LatencyComp := Interpol / 1000
ExtraPol := Interpol * 12
        Send {Enter}
        Send,SettingsManager.floatSet GSDefaultLatencyCompensation %LatencyComp% {Enter}
    Sleep 20
        Send,SettingsManager.U32Set GSExtrapolationTime{Space} %ExtraPol% {Enter}
    Sleep 20
        Send,SettingsManager.U32Set GSInterpolationTime{Space} %Interpol% {Enter}
Sleep 50
    Send {Shift Up}
    Send {Alt Up}
return

;~F12::
;    Send,SettingsManager.boolSet GSExtrapolateFrame 1 {Enter}
;return

/*
======================================================
Create ini
======================================================
*/


CreateIni:
   IfNotExist %A_WinDir%\BF2HitFixer.ini
   {
      Empty = 
      FileAppend ,= BF2 Hitfixer =`n`n, %A_WinDir%\BF2HitFixer.ini
      IniWrite F11, %A_WinDir%\BF2HitFixer.ini, Hotkeys, HitfixerKey
   }
return

/*
======================================================
Read ini
======================================================
*/

ReadIni:
   IniRead v_Hitfix, %A_WinDir%\BF2HitFixer.ini, Hotkeys, HitfixerKey
return

/*
======================================================
Ingame Suspend 
======================================================
*/

$Pause::
Suspend, Toggle
Menu, Tray, ToggleCheck, Suspend
SoundBeep, 500, 100
return