BF2S Forums Script/app to pull a daily image off a blog and wallpaper it?

#SingleInstance force
#NoEnv

; change this if you want the images to be saved in a folder other than the one the script is in
; eg. SetWorkingDir, c:\users\me
SetWorkingDir, %A_ScriptDir%

;#NoTrayIcon ;uncomment this to hide the tray icon

; change this variable to one of the following:
; CENTER|TILE|STRETCH|MAX
WallpaperOptions = STRETCH

; rss url
rss = http://feeds.feedburner.com/SomeoneOnceToldMe



; constants
Gui, +LastFound
hwnd := WinExist()
WM_WTSSESSION_CHANGE := 0x02B1
WTS_SESSION_LOGON := 0x5
WTS_SESSION_UNLOCK := 0x8

; hook messages
DllCall("wtsapi32.dll\WTSRegisterSessionNotification", uint, hwnd, uint, 1)
OnMessage(WM_WTSSESSION_CHANGE, "fn")
OnMessage(WTS_SESSION_LOGON, "fn")

; run once when script is started
fn(0,0)
return


fn(wparam, lparam)
{
    global rss, WallpaperOptions
    tempfile = sotm.rss
    
    ; downlaod the rss file and extract the image url
    UrlDownloadToFile, %rss%, %tempfile%
    FileRead, rssdata, %tempfile%
    FileDelete, %tempfile%
    if not RegExMatch(rssdata, "is)^.*?<item>.*?<description>.*?img src=""(.*?)""", m)
        return false
    
    ; check if we already have this image
    SplitPath, m1, imgname
    if FileExist(imgname)
        return true
    
    ; download the image and set it as wallpaper
    UrlDownloadToFile, %m1%, %imgname%
    COM_Init() ; thanks to sean for this code    http://www.autohotkey.com/forum/topic16905.html
    pad := COM_CreateObject("{75048700-EF1F-11D0-9888-006097DEACF9}", "{F490EB00-1240-11D1-9888-006097DEACF9}")
    DllCall(NumGet(NumGet(1*pad)+28), "Uint", pad, "int64P", WPSTYLE_%WallpaperOptions%<<32|8, "Uint", 0) ;SetWallpaperOptions
    DllCall(NumGet(NumGet(1*pad)+20), "Uint", pad, "Uint", COM_Unicode4Ansi(wFile,imgname), "Uint", 0) ;SetWallpaper
    ; AD_APPLY_ALL | AD_APPLY_FORCE | AD_APPLY_BUFFERED_REFRESH = 7 | 8 | 16 = 31
    DllCall(NumGet(NumGet(1*pad)+12), "Uint", pad, "Uint", 31) ;ApplyChanges
    COM_Release(pad)
    COM_Term()
}